Многие пользователи знают, что универсальный медиаплеер VLC умеет воспроизводить видео с сайта YouTube — достаточно загрузить адрес страницы с видео через меню Файл > Открыть сеть (File > Open Network). Однако эту процедуру можно свести к одному-единственному щелчку мыши, создав при помощи «Автоматора» элементарную службу OS X.
Преимуществ у такого способа просмотра ютьюбовского видео можно назвать сразу несколько. Во-первых, VLC автоматически загружает видео в самом лучшем качестве из доступных вариантов — причем без рекламы и всплывающих надписей-ссылок. Во-вторых, при воспроизведении в VLC у пользователя в распоряжении весь необходимый арсенал «улучшалок» картинки — в том числе возможность кадрирования и изменения соотношений сторон кадра (иногда бывает необходимо). В-третьих, ссылки на понравившиеся видеоролики можно собрать в плейлист и запускать их, не загружая сайта YouTube. Можно, конечно, вспомнить и о функции сохранения потокового видео, но для этого можно установить более эффективное средство.
В чем суть предлагаемой службы «Автоматора». Вызывая ее, вы передаете адрес текущей страницы в плейлист VLC, после чего плеер перейдет к новодобавленной ссылке и начнет воспроизведение. Этот нехитрый алгоритм реализуется посредством одного действия — сценария AppleScript (полный его текст приводится ниже):
Обратите внимание, что в шапке алгоритма не указан тип данных. Это значит, что перед запуском службы ничего специально выделять не нужно. Во втором же выпадающем списке желательно указать, из какой программы вы собираетесь запускать эту службу. Приведенный ниже программный код позволяет использовать браузер Safari, Google Chrome, Firefox или Opera — при запуске службы из других программ загрузка веб-адреса в VLC выполняться не будет.
Полный код сценария таков:
on run {input, parameters}
set _URL to GetCurrentURL()
if _URL starts with "http://www.youtube.com" then
tell application "VLC"
OpenURL _URL --> загрузка URL в плейлист VLC
next --> переход плеера к только что добавленному пункту плейлиста
play --> начало воспроизведения
activate --> принудительный вывод окна плеера на передний план
end tell
end if
end run
on GetCurrentApp() --> Определение имени активного приложения
tell application "System Events"
get short name of the first process whose frontmost is true
end tell
end GetCurrentApp
on GetCurrentURL() --> Определение адреса текущей веб-страницы
set _app to GetCurrentApp()
if _app is in {"Safari", "WebKit"} then --> Если вызов из Safari
using terms from application "Safari"
tell application "Safari"
get URL of current tab of window 1
end tell
end using terms from
else if _app is "Chrome" then --> Если вызов из Chrome
tell application "Google Chrome"
get URL of active tab of first window
end tell
else if _app is "Firefox" then --> Если вызов из Firefox
tell application "System Events"
keystroke "l" using {command down}
keystroke "c" using {command down}
delay 1.0
get the clipboard as string
end tell
else if _app is "Opera" then --> Если вызов из Opera
tell application "Opera"
get URL of front document as string
end tell
end if
end GetCurrentURL
Сохранив службу, например, под именем Загрузить веб-адрес в VLC, откройте любую страницу YouTube с видеороликом и через основное меню браузера вызовите только что сохраненную службу. В ответ на это будет запущен VLC (конечно, при условии, что он у вас установлен) — и начнется воспроизведение видео. Повторный вызов службы создаст в плейлисте плеера новый пункт и начнет его воспроизведение.
Хозяйке на заметку. Не забывайте о том, что любому пункту основного меню мак-программ можно назначать клавиатурные сокращения — через программу «Системные настройки» (System Preferences), модуль Клавиатура (Keyboard), вкладку Сочетания клавиш (Keyboard Shortcuts), раздел Сочетания клавиш для программы (Application Shortcuts). Назначив клавиатурное сокращение для пункта Загрузить веб-адрес в VLC, созданную службу «Автоматора» можно вызывать не отрывая рук от клавиатуры.
Интересно, что при этом программа покажет в окне сведений о текущем видео (клавиши command+I). VLC подгружает основные сведения о ролике, а также — приятный бонус — физический адрес видеофайла на серверах YouTube. Выделив и скопировав содержимое поля Location, его можно вставить в менеджер загрузок — и скачать видео к себе на компьютер.
